#filename = 'FiberHarp.dat' generated by analyze_harp from harp_plane_hit.dat and by analyze_fibers_harp from fiber_hits.dat
#time_bin = 10.e-9
min(a,b)=(a< b) ? a:b
do for [harp=1:4] {

set terminal pdf enhanced fontscale 0.5 size 6.0in, 4.0in

if(harp == 1 || harp == 3 ){
tx='<y>'
txx='<y-width>'
xr=5}

if(harp == 2 || harp == 4){
tx='<x>'
txx='<x-width>'
xr=0.5}

harp_num=sprintf("%i",harp)
tbin=sprintf("%i",time_bin*1.e9)
output_file = 'FiberHarp'.harp_num.'-'.tbin.'-Position.pdf'
set out output_file
print 'Harp '.harp_num
set label 'Harp '.harp_num at graph 0.1, 1.04
set multiplot #title filename noenhance
set label 'plotting_scripts/harp_tunes.gnu' at graph 1.02,0.02 rotate left font 'Verdana,6' noenhance
set size 0.5, 0.5
set origin 0.,0.5
unset xrange
set xrange [0:]
set xlabel 'Time [us]'
set ylabel 'Vertical displacement [mm]'

# average 10 consecutive points
back1=0
back2=0
back3=0
back4=0
back5=0
back6=0
back7=0
back8=0
back9=0
back10=0
samples(x) = $0>9 ? 10 :($0+1)
avg10(x) = (shift10(x),(back1+back2+back3+back4+back5+back6+back7+back8+back9+back10)/samples($0))
shift10(x) = (back10 = back9, back9 = back8, back8=back7, back7=back6, back6=back5, back5=back4, back4=back3, back3=back2, back2=back1, back1=x)
init(x) = (back1=back2=back3=back4=back5=back6=back7=back8=back9=back10=sum=0)

if(time_bin < 10.e-9) {
plot filename u ($2*time_bin*1.e6):($1 == harp ? (avg10($3)*1000):1/0) w l t tx
} else {
plot filename u ($2*time_bin*1.e6):($1 == harp ? ($3*1000):1/0) w l t tx
}

set size 0.5,0.5
unset label
unset ylabel
set xlabel 'frequency [MHz]'
set origin 0.5,0.
max_freq = 1/time_bin/1.e6/2
set xrange [0.1:min(max_freq,10)]
plot filename u 6:($1 == harp ? ($9*2+$10**2)**.5:1/0) w boxes t tx.' fft'
set origin 0.5,0.5
unset xlabel
plot filename u 6:($1 == harp ? ($11**2+$12**2)**.5:1/0) w boxes t txx.' fft'
set origin 0.,0.
unset xlabel
set xlabel 'frequency [MHz]'
set timestamp rotate font 'Verdana,6'
set xrange [0.1:xr]
plot filename u 6:($1 == harp ? ($9**2+$10**2)**.5:1/0) w boxes t tx.' fft'
unset multiplot
unset terminal
unset timestamp
print 'write '.output_file 
}